Belajar Microsoft Excel: Rumus Excel Countif: Menjumlah Sel Dengan Syarat

Fungsi Excel COUNTIF

Fungsi COUNTIF Dalam Rumus Excel sanggup digunakan untuk menjumlah banyaknya sel yang menyanggupi syarat , tolok ukur atau keadaan tertentu. Misalnya menjumlah banyaknya sel kosong , menjumlah sel berisi bilangan tertentu , sel berisi tanggal tertentu , maupun sel berisi text atau karakter tertentu. Fungsi COUNTIF tersedia pada banyak sekali model excel , baik model 2003 , 2007 , 2010 , 2013 dan 2016. 

Belajar excel kali ini akan membahas fungsi COUNTIF secara rinci , dimulai dari pembahasan syntax dan dasar cara penggunaannya , lalu dilanjutkan dengan pembahasan beberapa pola penerapan rumus COUNTIF. Pada belahan final akan diulas problem solving atas beberapa problem dan pertanyaan seputar penggunaan fungsi COUNTIF dalam rumus Excel.

  • Syntax dan Cara Penggunaan Fungsi COUNTIF
  • Contoh-Contoh Cara Menggunakan Fungsi COUNTIF Pada Excel
  • Rumus COUNTIF Untuk Text dan Bilangan (Exact Match)
  • Rumus COUNTIF Menggunakan Karakter Wildcard (Partial Match)
  • Menghitung Banyaknya Sel Kosong atau Sebaliknya
  • Menghitung Sel Jika Berisi Bilangan Lebih Besar , Lebih Kecil , Atau atau Sama Dengan
  • Rumus COUNTIF Untuk Tanggal
  • Rumus COUNTIF Dengan Dua Kriteria
  • Menghitung Banyaknya Data Duplikat
  • Menjawab Beberapa Permasalahan Seputar Rumus COUNTIF

Syntax dan Cara Penggunaan Fungsi COUNTIF

COUNTIF digunakan untuk menjumlah banyaknya sel dengan keadaan atau tolok ukur tertentu. Syntax-nya pun sungguh sederhana dan cuma memiliki 2 argumen:

=COUNTIF(range , criteria)

range : berupa tumpuan mewakili satu atau beberapa sel untuk dijumlah , misalnya A1:A10

criteria: Kondisi tertentu yang menjadi syarat apakah sel tersebut akan dijumlah atau tidak. Argumen tolok ukur sanggup berupa bilangan , tanggal , string yang mewakili persamaan , maupun text tertentu. Kriteria ini juga sanggup disimpan dalam sel yang dijadikan referensi.

Rumus berikut ialah pola sederhana cara menggunakan fungsi COUNTIF untuk menjumlah berapa kali karyawan suatu perusahaan yang tidak hadir lantaran sakit dalam kurun waktu 10 hari.

=COUNTIF(B2:B11 ,”sakit”)

Jika criteria disimpan dalam sel E1 , maka rumus berikut lebih disarankan lantaran lebih fleksible:

=COUNTIF(B2:B11 ,E1)

Fungsi COUNTIF Menghitung Absensi

Catatan: criteria bersifat case insensitif sehingga tidak ada problem apakah penulisan criteria menggunakan karakter kecil ataupun karakter kapital.

Contoh-Contoh Rumus Fungsi COUNTIF

Ternyata faedah fungsi COUNTIF tidak sesederhana syntax nya. Dengan penyesuaian argumen criteria , maka kita akan mendapat kegunaan beragam dari fungsi COUNTIF.

Rumus COUNTIF untuk Text dan Bilangan (exact match)

Mari kita lihat lembali pola rumus COUNTIF untuk menjumlah jumlah hari ketidakhadiran karyawan sakit menyerupai dicontohkan pada sub belahan pertama.

=COUNTIF(B2:B11 ,”sakit”)

Perhatikan bagian-bagian dari argumen fungsi tersebut:

range = yakni berupa tumpuan sel B2:B11

Tanda koma ( ,) memiliki fungsi selaku delimiter , atau pemisah argumen. Jika komputer anda menggunakan seting Indonesia , mungkin delimiternya yakni tanda titik koma atau semicolon (;)

Sebuah  kata dalam tanda kutip , yakni kata “sakit” berperan selaku argumen criteria. Daripada mengetikan  text secara pribadi , kita sanggup menggunakan suatu tumpuan sel yang mengandung text atau kata yang menjadi kriteria. Anggaplah criteria ketidakhadiran disimpan di sel E1 , maka rumus untuk menjumlah banyaknya ketidakhadiran tertentu sanggup dituliskan selaku berikut:

=COUNTIF(B2:B11 ,E1)

Contoh diatas menggunakan kritera text. Bagaimana dengan tolok ukur bilangan?

Misalnya untuk menjumlah berapa orang anak berumur 10 tahun sanggup diilustrasikan selaku berikut:

Fungsi COUNTIF Menghitung Banyaknya Usia Tertentu
Perhatikan rumus yang digambarkan dalam ilustsrasi tersebut:
=COUNTIF(B2:B9 ,10)
Berbeda dengan tolok ukur text , penulisan tolok ukur bilangan tidak membutuhkan tanda petik.
Dalam prakteknya , mungkin kita akan lebih gampang menggunakan tolok ukur yang disimpan dalam tumpuan sel ketimbang mengetikannya pribadi pada rumus. Anggaplah tolok ukur disimpan dalam sel E1 , maka rumusnya sanggup ditulis begini:

=COUNTIF(B2:B9 ,E1)

Rumus COUNTIF Menggunakan Karakter Wildcard


Penggunaan karakter wilcard dalam rumus COUNTIF sungguh memiliki fungsi untuk menjumlah banyaknya sel berisi text dengan keyword tertentu. Sebagai pola yakni untuk menjumlah jumlah nama siswa yang memiliki satu atau beberapa karakter permulaan tertentu atau mengandung kata tertentu (misal: marga atau nama keluarga)
Anggaplah kita memiliki sekumpulan nama siswa yang disimpan pada kolom A (range A2:A9) dalam lembar kerja excel / spreadsheet.
Pertanyaan: Bagaimana rumus excel untuk menjumlah berapa banyak nama siswa yang diawali karakter tertentu? anggaplah nama siswa tersebut diawali karakter “B”.
Jawaban: Gunakan fungsi COUNTIF dengan argumen criteria berupa karakter “B” disertai karakter wilcard asterisk (*). Sehingga rumus sanggup dituliskan selaku berikut:
=COUNTIF(A2:A9 ,”B*”)
Seandainya text criteria disimpan di sel G1 ,maka rumus COUNTIF diatas sanggup diubah menjadi:

=COUNTIF(A2:A9 ,G1&”*”)

Fungsi COUNTIF Menghitung Nama Dengan Huruf Awal Tertentu

Silahkan dicoba dengan manipulasi banyak sekali posisi kata kunci:

Menghitung banyaknya siswa yang mengandung karakter  tertentu , tidak menghiraukan dimana posisi karakter tersebut:


=COUNTIF(A2:A9 ,”*”&G1&”*”)

Menghitung banyaknya siswa dengan karakter final tertentu

=COUNTIF(A2:A9 ,”*”&G1)

Dalam prakteknya kita sanggup menggunakan text yang panjangnya lebih dari satu karakter selaku tolok ukur , misalnya nama depan dan nama belakang. Silahkan dicoba dan dimodifikasi isi sel G1 dengan text yang lebih panjang dan  bervariasi. Kemudian amati hasil yang diperoleh rumus COUNTIF.

Baca Juga  101 Fungsi Excel dan cara penggunaanya

Perlu diingat 

  • Karakter wilcard asterisk (*) digunakan untuk mewakili karakter yang tidak diputuskan jumlahnya , sehingga sungguh sesuai untuk mencari nama dengan karakter permulaan tertentu , lantaran karakter yang menyusun nama , jumlahnya tidak tentu.
  • Jika jumlah karakternya diputuskan maka gunakanlah karakter wildarcd tanda tanya (?)
  • Untuk memperlakukan karakter wilcard selaku karakter biasa , gunakan tanda gelombang () sebelum mengetikan karakter wilcard

Berikut pola cara penulisan karakter wilcard dalam argumen critera fungsi COUNTIF

Contoh
Keterangan
“Mr *”
Mewakili text “Mr “ disertai karakter bebas yang lain dengan jumlah tidak dibatasi
“Mr ?????”
Mewakili text “Mr “ disertai 5 karakter bebas setelahnya.
“Mr ***”
Secara persis mewakili karakter “Mr ***”
“Mr ???”
Secara persis mewakili karakter “Mr ???”

Rumus Excel COUNTIF Untuk Menghitung Banyaknya Sel Kosong/Tidak Kosong

Contoh-contoh rumus excel berikut akan menampilkan bagaimana fungsi COUNTIF  dapat digunakan untuk menjumlah banyaknya sel kosong (blank) dan sel tidak kosong (non blank) dalam range tertentu.

COUNTIF not blank – Menghitung Sel Tidak Kosong

Untuk menjumlah banyaknya sel tidak kosong , kita sanggup menggunakan rumus selaku berikut:

=COUNTIF(range ,”*”)

atau

=COUNTIF(range ,”<>“&””)


COUNTIF blank – Menghitung Sel Kosong

Sebaliknya , kita juga sanggup menjumlah banyaknya sel  kosong. Untuk itu gunakan budi terbalik dari pola sebelumya , sehingga rumus menjadi:

=COUNTIF(range ,”<>“&”*”)

atau

 =COUNTIF(range ,””)

Perlu diingat: Sebenarnya excel sudah menawarkan fungsi khusus untuk menjumlah sel kosong dalam range tertentu , yakni fungsi COUNTBLANK , Cukup ketikan =COUNTBLANK(range) , maka kita sudah dapatkan banyaknya sel kosong dalam range.

Menghitung Banyaknya Sel Berisi Bilangan Dengan Nilai Lebih Besar , Lebih Kecil atau Sama Dengan Nilai Kriteria.

Apa yang perlu dijalankan untuk menjumlah banyaknya sel yang memiliki nilai lebih besar , lebih kecil , atau sama dengan tolok ukur yang ditentukan?

Cukup tambahkan saja operator komparasi yang sempurna sesuai tolok ukur , menyerupai pola dalam tabel berikut:

Criteria
Contoh Rumus
Keterangan
Hitung jika  nilai lebih dari
=COUNTIF(B2:B9 ,”>11″)
Menghitung banyaknya sel dalam range B2:B9 yang bernilai lebih dari 11
Hitung bila nilai kurang dari
=COUNTIF(B2:B9 ,”<11")
Menghitung banyaknya sel dalam range B2:B9 yang bernilai kurang dari 11
Hitung bila nilai sama dengan
=COUNTIF(B2:B9 ,”=11″)
Menghitung banyaknya sel dalam range B2:B9 yang bernilai sama dengan 11
Hitung bila nilai tidak sama dengan
=COUNTIF(B2:B9 ,”<>11″)
Menghitung banyaknya sel dalam range B2:B9 yang nilainya tidak sama dengan 11
Hitung bila nilai sekurang-kurangnya sama dengan
=COUNTIF(B2:B9 ,”>=11″)
Menghitung banyaknya sel dalam range B2:B9 yang bernilai 11 atau lebih.
Hitung bila nilai optimal sama dengan
=COUNTIF(B2:B9 ,”<=11")
Menghitung banyaknya sel dalam range B2:B9 yang bernilai 11 atau kurang.

Perhatikan: sama halnya dengan penggunaan fungsi SUMIF , maka dalam fungsi COUNTIF juga kita mesti menggunakan tanda petik dua untuk tolok ukur yang menggunakan kombinasi bilangan dan operator komparasi.

Contoh rumus COUNTIF dalam tabel di atas menggunakan tolok ukur yang diketikan pribadi dalam rumus. Jika kita ingin menempatkan tolok ukur dalam sel mudah-mudahan kedepannya sanggup lebih gampang mengganti tolok ukur tanpa mengganti rumus. Maka gunakan operator ampersand (&) untuk memadukan operator komparasi dengan tumpuan yang menjadi kriteria.

Contohnya:
=COUNTIF(B2:B9 ,”>11″)

Jika tolok ukur disimpan di sel D1 , maka rumus tersebut sanggup dirubah menjadi:
=COUNTIF(B2:B9 ,”>”&D1)

Untuk lebih gampang memahaminya , amati gambar berikut:

Fungsi COUNTIF Usia

Sebagian pembaca mungkin bertanya-tanya dalam hati. Bagaimana cara memperlakukan tanda lebih dari (>) , kurang dari (<) dan sama dengan (=) selaku karakter biasa , bukan selaku operator komparasi (perbandingan). Untuk kasus tersebut kita sanggup menggagungkan operator komparasi dengan karakter wilcard. Misalnya : =COUNTIF(B2:B9 ,”*>11*”)

Formula tersebut akan menjumlah banyaknya sel dalam range B2:B9 dimana sel tersebut mengandung text “>11” , Dalam pola tersebut , tanda lebih dari (>) terbaca selaku karakter biasa

Menggunakan Fungsi COUNTI F dengan Kriteria Tanggal

Jika kita ingin menjumlah banyaknya tanggal tertentu , maka gunakan fungsi COUNTIF dengan criteria data tanggal. Hal serupa sanggup dijalankan untuk menjumlah berapa banyak data tanggal sebelum atau sesudah tanggal tertentu , pastinya nyaris sama penggunannya dengan fungsi COUNTIF tolok ukur bilangan yakni menggunakan operator komparasi “<” , “>” , dan “=”

Perhatikan pola rumus dalam tabel berikut:

Criteria
Contoh Rumus
Keterangan
Menghitung banyaknya tanggal tertentu
=COUNTIF(B2:B9 ,”12/15/2016″)
Menghitung banyaknya tanggal 15 Desember 2016 pada range B2:B9
Menghitung banyaknya tanggal tertentu dan tanggal sesudahnya.
=COUNTIF(B2:B9 ,”>=12/15/2016″)
Menghitung banyaknya tanggal 15 Desember 2016 dan tanggal sesudahnya pada range B2:B9
Menghitung banyaknya tanggal dimulai dari beberapa hari sebelum tanggal ditentukan
=COUNTIF(B2:B9 ,”>=”&G1-7)
Menghitung banyaknya tanggal pada range B2:B9 , dimulai dari 7 hari sebelum tanggal yang disimpan di sel G1

Dengan memperhatikan  contoh rumus atau formula dalam tabel diatas , kita sanggup mengetikan pribadi tanggal selaku tolok ukur (contoh: “12/15/2016”) dan menggunakan tumpuan sel (contoh : G1).

Baca Juga  Cara Membuat Grafik di Excel

Selain dari kedua cara penulisan argumen tolok ukur diatas (ketik pribadi tanggal maupun tumpuan sel) , kita juga sanggup menggunakan fungsi yang lain selaku criteria. Misalnya fungsi TODAY.  Fungsi ini memiliki fungsi untuk mendapat data tanggal kini sesuai setting komputer.

Criteria
Contoh Rumus
Menghitung banyaknya tanggal yang serupa dengan tanggal sekarang
=COUNTIF(B2:B9 ,TODAY())
Menghitung banyaknya tanggal sebelum tanggal sekarang
=COUNTIF(B2:B9 ,”<"&TODAY())
Menghitung banyaknya tanggal sesudah tanggal sekarang
=COUNTIF(B2:B9 ,”>”&TODAY())
Menghitung banyaknya tanggal yang serupa dengan tanggal sepekan kedepan dari sekarang
=COUNTIF(B2:B9 ,”=”&TODAY()+7)
Menghitung banyaknya tanggal dimulai tanggal tertentu tetapi kurang dari tanggal tertentu
=COUNTIF(B2:B9 , “>=12/1/2016”)-COUNTIF(B2:B9 , “>12/15/2016”)

Berikut pola formula menggunakan fungsi TODAY selaku argumen criteria dalam fungsi COUNTIF. Rumus ini digunakan untuk menjumlah banyaknya tagihan yang sudah jatuh tempo.

Rumus COUNTIF Tanggal

Keterangan: postingan ini ditulis pada tanggal 16 Desember 2016 , sehingga rumus TODAY() menciptakan nilai tanggal 16 Desember 2016

Fungsi COUNTIF dengan Kriteria Ganda

Sebenarnya fungsi COUNTIF di excel tidak di-design untuk menjumlah banyaknya sel yang menyanggupi tolok ukur atau keadaan yang lebih dari satu. Namun demikian fungsi ini juga sanggup digunakan untuk kebutuhan tersebut utamanya pada excel model 2003 atau yang lebih lama. Untuk excel model 2007 ke atas , kiprah ini sudah digantikan oleh fungsi COUNTIFS (lihat: ada karakter “S”)

Contoh 1 : Fungsi COUNTIF dengan Kondisi Ganda berupa bilangan

Fungsi COUNTIF tolok ukur ganda biasanya digunakan untuk menjumlah banyaknya data yang menyanggupi rentang tolok ukur atau keadaan tertentu , dibatasi nilai minimal dan nilai maksimal.

Misalnya untuk menjumlah jumlah anak berumur 10 s.d 12 tahun sesuai data umur pada range B2:B9 maka sanggup dirumuskan selaku berikut:

=COUNTIF(B2:B9 ,”>=10″)-COUNTIF(B2:B9 ,”>12″)

Rumus COUNTIF Rentang Umur

Contoh 2 : Fungsi COUNTIF dengan Kondisi Ganda berupa Text

Mari kita amati satu lagi pola rumus COUNTIF dengan dua tolok ukur untuk menjumlah banyaknya item barang yang mengandung text tertentu.

Anggaplah anda sedang belanja di pasar buah , dan ingin menjumlah berapa banyak item belanjaan buah jeruk dan mangga.

=COUNTIF(A2:A9 ,”*Jeruk*”)+COUNTIF(A2:A9 ,”*mangga*”)

Rumus COUNTIF Syarat Ganda

Perhatikan penggunaan karakter wildcard asterisk pada pola di atas. Karakter tersebut digunakan untuk mewakili sejumlah karakter yang lain tergolong string kosong (tidak ada karakter sama sekali) , baik sebelum maupun sesudah kata kunci. Sehingga pola rumus tersebut sanggup menjumlah semua benda yang mengandung kata mangga atau jeruk.

Dengan cara yang serupa kita juga sanggup menyertakan fungsi COUNTIF yang lain untuk menjumlah lebih banyak kriteria.

Contohnya: untuk menjumlah semua item belanja jeruk , mangga dan pisang maka sanggup menggunakan rumus berikut:

=COUNTIF(A2:A9 ,”*Jeruk*”)+COUNTIF(A2:A9 ,”*mangga*”)+COUNTIF(A2:A9 ,”*pisang*”)

Menggunakan Fungsi COUNTIF untuk Menemukan Nilai Duplikat dan Nilai Unik

Kegunaan yang lain dari fungsi COUNTIF pada Excel yakni untuk mendapatkan nilai duplikat , baik pada satu kolom , antara dua kolom maupun dalam baris.

Contoh 1 : Menemukan dan Menghitung Banyaknya Duplikat dalam 1 Kolom

Sebenarnya dari permulaan pembahasan kita sudah mengetahui cara menjumlah banyaknya duplikat data di excel. Hal ini lantaran fungsi COUNTIF sendiri memiliki fungsi untuk menjumlah sel dengan keadaan yang sama.  Artinya bila kita menjumlah sel dengan keadaan yang persis sama , maka kita juga sanggup mengenali adanya duplikat bila rumus menciptakan nilai lebih dari satu.

Menggunakan Kolom Bantu

Untuk duplikat , kita sanggup menandainya dengan sumbangan operator komparasi lebih dari (>) untuk memeriksa hasil fungsi COUNTIF. Jika hasil lebih dari 1 maka ditandai TRUE , dan bila tidak ada dplikat maka ditandai FALSE. cek TRUE/FALSE ini disimpan dalam suatu kolom bantu.

Sebagai pola , rumus sederhana =COUNTIF($A$2:$A$10 ,$A2)>1 sanggup digunakan untuk memeriksa apakah nilai dalam sel A2 memiliki duplikat atau tidak pada range A2:A10. Dengan mengcopy rumus tersebut ke baris dibawahnya maka kita sanggup memeriksa semua duplikat pada range A2:A10

Selanjutnya , untuk menjumlah banyaknya duplikaat yakni dengan carmenghitung banyaknya TRUE dalam kolom bantu menyerupai rumus berikut:
=COUNTIF(B2:B10 ,TRUE)

Tanpa Kolom Bantu

Untuk menjumlah banyaknya nilai duplikat tanpat kolom bantu , maka kita sanggup menggunakan fungsi SUMPRODUCT yang dikombinasikan dengan COUNTIF.

=SUMPRODUCT((COUNTIF(A2:A10 ,A2:A10)>1)*(A2:A10<>“”))

Untuk lebih jelasnya , amati screenshoot berikut yang mengilustrasikan bagaimana cara menggunakan rumus excel untuk menjumlah nilai duplikat , baik menggunakan kolom bantu ataupun tidak.

Fungsi COUNTIF Menghitung Duplikat Dalam Kolom

Contoh 2 : Menghitung Banyaknya Duplikasi Antara Dua Kolom

Jika kita memiliki dua list terpisah , katakanlah  list nama pada kolom B dan C. Kemudian kita ingin mengenali berapa kali nama-nama tersebut timbul pada kedua kolom.

Cara menghitungnya yakni menggunakan kombinasi antara fungsi SUMPRODUCT dengan fungsi COUNTIF

Menghitung banyaknya nama di kolom A yang timbul kembali di kolom B

=SUMPRODUCT((COUNTIF(A2:B10 ,B2:B10)>1)*(B2:B10<>“”))

Menghitung banyaknya nama di kolom B yang tidak ada di kolom A

=SUMPRODUCT((COUNTIF(A2:B10 ,B2:B10)=1)*(B2:B10<>“”))

Rumus COUNTIF Menghitung Duplikat Dua Kolom

Contoh diatas cuma digunakan untuk list hingga baris 10. Untuk data yang lebih banyak silahkan dimodifikasi tumpuan range tersebut. Misal: A2:B10 menjadi A2:B100 atau A2:B1000 dan seterusnya.

Contoh 3 : Menghitung Banyaknya Nilai Duplikat dan Nilai Unik dalam Sebuah Baris

Kombinasi antara fungsi SUMPRODUCT  dan fungsi COUNTIF  juga diinginkan untuk  menghitung banyaknya nilai duplikat maupun nilai unik dalam baris ,

Baca Juga  Belajar Microsoft Excel: Cara Cepat Isi Sel Kosong

Menghitung banyaknya nilai duplikat dalam baris (range A1:M1)

=SUMPRODUCT((COUNTIF(A1:M1 ,A1:M1)>1)*(A1:M1<>“”))

Menghitung banyaknya nilai unik dalam baris (range A1:M1)

=SUMPRODUCT((COUNTIF(A1:M1 ,A1:M1)=1)*(A1:M1<>“”))

Fungsi COUNTIF Duplikat Dalam Row

Penjelasan dan Pemecahan Masalah Seputar Penggunaan Fungsi COUNTIF

Setidaknya ada 5 problem yang paling kerap ditanyakan seputar penggunaan fungsi COUNTIF pada Excel. Berikut akan  akan disampaikan kelima problem tersebut dan solusinyaj. Semoga bermanfaat.

1. COUNTIF Pada Range Terputus

Pertanyaan: Apakah Fungsi COUNTIF sanggup digunakan kepada range yang terputus , atau beberapa sel yang diseleksi.

Jawaban : Fungsi COUNTIF tidak sanggup melakukan pekerjaan pada range yang terputus , adonan beberapa range atau beberapa sel.

Solusi: untuk mendapat perkiraan pada beberapa range atau sel yang terpisah maka kita mesti menggunakan beberapa fungsi COUNTIF.

Rumus yang salah:
=COUNTIF(A2 ,B5 ,C2 ,”>0″)

Rumus yang Benar:
 =COUNTIF(A2 ,”>0″) + COUNTIF(B5 ,”>0″) + COUNTIF(C2 ,”>0″)

Alternatif penyelesaian yang lain yakni menggunakan kombinasi fungsi SUM , COUNTIF dan INDIRECT
Printscreen berikut menggambarkan cara penggunaan jumlah bilangan 0 pada dua range yang berlainan yakni range B2:B10 dan C2:C10

Cara 1 : Menggunakan beberapa fungsi COUNTIF

=COUNTIF(B2:B10 ,0)+COUNTIF(C2:C10 ,0)

Cara 2 : Menggunakan kombinasi SUM , COUNTIF dan INDIRECT.

=SUM(COUNTIF(INDIRECT({“B2:B10″ ,”C2:C10”}) ,0))

Kombinasi SUM , COUNTIF INDIRECT

2. Ampersand dan tanda petik dalam rumus COUNTIF

Pertanyaan: Kapan kita perlu menggunakan tanda ampersand (&) dan tanda petik (“”) di dalam formula COUNTIF?

Jawaban: Penggunaan ampersand dan tanda kutip dalam fungsi COUNTIF mungkin agak membingungkan. Saya sendiri mencicipi hal demikian dikala pertama kali bergelut dengan rumus ini. Namun dengan menelaahnya dengan sesama , kita akan mengetahui bahwa penggunaan ampersand dan tanda  petik dua ternyata yakni untuk membangun string argumen criteria. Ikuti hukum main berikut dalam menggunakan ampersand dan tanda petik:

  • Jika kita menggunakan bilangan atau tumpuan sel selaku criteria yang persis sama (exact match) maka tanda ampersand maupun tanda petik tidak diperlukan

Contoh:
=COUNTIF(A1:A10 ,10)
=COUNTIF(A1:A10 ,C1

  • Jika tolok ukur yang digunakan berupa text , karakter wildcard atau operator komparasi yang digabung dengan bilangan maka gunakanlah tanda petik.

Contoh:
=COUNTIF(A2:A10 ,”pisang”)
=COUNTIF(A2:A10 ,”*”)
=COUNTIF(A2:A10 ,”>10″)

  • Jika kita menggunakan expresi budi dengan operator komparasi yang mengacu pada sel tumpuan atau fungsi excel yang lain , maka kita perlu meletakan operator komparasi dalam tanda petik (“”) dan menggunakan ampersand  (&) untuk memadukan operator komparasi dengan tumpuan atau fungsi lainnya.

Contoh:
=COUNTIF(A2:A10 ,”>”&D2)
=COUNTIF(A2:A10 ,”<="&TODAY())

  • Jika kita merasa ragu apakah ampersand dan tanda petik diinginkan atau tidak , maka kita sanggup menjajal keduanya. Biasanya kedua cara tersebut sama-sama melakukan pekerjaan dan menciptakan nilai yang sama.

Contoh:
Formula =COUNTIF(C2:C8 ,”<=5")
Sama saja alhasil bila dituliskan =COUNTIF(C2:C8 ,”<="&5)

3. Menghitung Banyaknya Sel Dengan Warna Tertentu


Pertanyaan : Bagaimana cara menjumlah sel menurut warna

Jawaban : Sangat disayangkan bahwa fungsi COUNTIF ternyata tidak sanggup digunakan untuk menjumlah banyaknya sel menurut warna.

Solusi : Satu-satunya cara yang sanggup digunakan untuk menjumlah banyaknya sel menurut warna yakni menggunakan macro atau code VBA.

Contoh:

Code VBA berikut sanggup digunakan untuk menjumlah banyaknya sel pada rangeWarna sesuai warna pada selAcuan

Copy code berikut pada modul standar dalam vba editor (untuk membuka vba editor , tekan ALT + F11 , lalu tekan insert , dan tekan module untuk menimbulkan module standar baru)

Function hitungWarna(selAcuan As Range , rangeWarna As Range)
Dim sel As Range
For Each sel In rangeWarna
    If sel.Interior.Color = selAcuan.Interior.Color Then
        hitungWarna = hitungWarna + 1
    End If
Next
End Function

Fungsi hitungWarna ini kita kenal selaku salah satu pola dari User Defined Function (UDF = fungsi yang dibentuk sendiri oleh user). Fungsi ini sanggup digunakan dalam lembar kerja excel menyerupai halnya menggunakan fungsi biasa ,

Contoh rumus :   =hitungwarna(D1 ,A2:A9)

Rumus tersebut digunakan untuk menjumlah sel pada range A2:A9 dengan warna yang serupa dengan sel D1.

Count If warna tertentu

5. Rumus COUNTIF menciptakan nilai Error #NAME?


Pertanyaan: Bagaimana cara menangani error #NAME? pada rumus COUNTIF?

Jawaban : error #NAME? disebabkan lantaran kesalahan penulisan/spelling fungsi , penulisan tumpuan , atau kesalahan penggunaan nama range dan nama sel.
Misal COUNTIF diketik COUNTIFF

Solusi : Cek kembali carai penulisan fungsi , range , nama range atau nama sel. Jika menggunakan nama range atau nama sel , cek apakah nama tersebut sudah didefinisikan.

5. Rumus Excel COUNTIF tidak bekerja

Pertanyaan : Saya sudah menciptakan rumus COUNTIF dengan syntax yang benar. Namun kenapa tidak menciptakan data yang benar dikala dicopy ke sel lain.

Jawaban: Hal ini disebabkan calculation setting di-set manual.

Solusi : Tekan F9 atau ubah calculation setting menjadi automatic. Penjelasan lebih rincian wacana kenapa rumus excel tidak berfngsi sanggup dibaca pada artikel: Rumus Excel Tidak Berfungsi? Inilah Penyebabnya!

Akhir kata , demikian pembahasan fungi COUNTIF dan contoh-contoh rumus terapannya dalam lembar kerja excel. Semoga bermanfaat.

Artikel Terkait


Referensi:
https://www.ablebits.com/office-addins-blog/2014/07/02/excel-countif-examples/

Need Help? Chat with us